RETURN expression;

帶有表達式的 RETURN 終止函數，並將 expression 的值傳回給呼叫者。 此形式用於不傳回集合的 PL/pgSQL 函數。

在傳回純量型別的函數中，表達式的結果將自動轉換為函數的傳回型別，如同指定所述。 但是要傳回複合（列）值，您必須編寫一個表達式，來交付精確請求的欄集合。 這可能需要使用顯式轉換。

如果您使用輸出參數宣告了該函數，請只編寫沒有表達式的 RETURN。 輸出參數變數的目前值將被傳回。

如果您宣告函數傳回 void，則可以使用 RETURN 語句提前退出函數； 但請不要在 RETURN 後面編寫表達式。

函數的傳回值不能保持未定義。 如果控制在未命中 RETURN 語句的情況下到達函數頂層區塊的末尾，則會發生執行階段錯誤。 但是，此限制不適用於具有輸出參數的函數和傳回 void 的函數。 在這些情況下，如果頂層區塊完成，則會自動執行 RETURN 語句。

一些範例

-- functions returning a scalar type
RETURN 1 + 2;
RETURN scalar_var;

-- functions returning a composite type
RETURN composite_type_var;
RETURN (1, 2, 'three'::text);  -- must cast columns to correct types

RETURN NEXT expression;
RETURN QUERY query;
RETURN QUERY EXECUTE command-string [ USING expression [, ... ] ];

當宣告 PL/pgSQL 函數傳回 SETOF sometype 時，要遵循的程序會略有不同。 在這種情況下，要傳回的各個項目由一系列 RETURN NEXT 或 RETURN QUERY 命令指定，然後使用沒有參數的最終 RETURN 命令來指示函數已完成執行。 RETURN NEXT 可以用於純量和複合資料型別； 對於複合結果型別，將傳回一整個 「表格」 結果。 RETURN QUERY 會將執行查詢的結果附加到函數的結果集合。 RETURN NEXT 和 RETURN QUERY 可以在單個傳回集合的函數中自由混合使用，在這種情況下，它們的結果將會被串連。

RETURN NEXT 和 RETURN QUERY 實際上並不會從函數返回，它們只是將零或多列附加到函數的結果集合。 然後，執行將繼續執行 PL/pgSQL 函數中的下一個語句。 隨著連續的 RETURN NEXT 或 RETURN QUERY 命令被執行，結果集合將被建立。 沒有參數的最終 RETURN 會導致控制退出函數（或者您可以直接讓控制到達函數的末尾）。

RETURN QUERY 有一個變體 RETURN QUERY EXECUTE，它指定要動態執行的查詢。 參數表達式可以經由 USING 插入到計算出的查詢字串中，就像在 EXECUTE 命令中一樣。

如果您使用輸出參數宣告了該函數，請只編寫沒有表達式的 RETURN NEXT。 在每次執行時，輸出參數變數的目前值將被儲存，以作為結果的一列最終傳回。 請注意，當有多個輸出參數時，您必須宣告該函數傳回 SETOF record，或者當只有一個型別為 sometype 的輸出參數時，您必須宣告該函數傳回 SETOF sometype，以便建立一個帶有輸出參數的傳回集合函數。

這是一個使用 RETURN NEXT 的函數範例

CREATE TABLE foo (fooid INT, foosubid INT, fooname TEXT);
INSERT INTO foo VALUES (1, 2, 'three');
INSERT INTO foo VALUES (4, 5, 'six');

CREATE OR REPLACE FUNCTION get_all_foo() RETURNS SETOF foo AS
$BODY$
DECLARE
    r foo%rowtype;
BEGIN
    FOR r IN
        SELECT * FROM foo WHERE fooid > 0
    LOOP
        -- can do some processing here
        RETURN NEXT r; -- return current row of SELECT
    END LOOP;
    RETURN;
END;
$BODY$
LANGUAGE plpgsql;

SELECT * FROM get_all_foo();

這是一個使用 RETURN QUERY 的函數範例

CREATE FUNCTION get_available_flightid(date) RETURNS SETOF integer AS
$BODY$
BEGIN
    RETURN QUERY SELECT flightid
                   FROM flight
                  WHERE flightdate >= $1
                    AND flightdate < ($1 + 1);

    -- Since execution is not finished, we can check whether rows were returned
    -- and raise exception if not.
    IF NOT FOUND THEN
        RAISE EXCEPTION 'No flight at %.', $1;
    END IF;

    RETURN;
 END;
$BODY$
LANGUAGE plpgsql;

-- Returns available flights or raises exception if there are no
-- available flights.
SELECT * FROM get_available_flightid(CURRENT_DATE);

IF boolean-expression THEN
    statements
END IF;

IF-THEN 陳述式是 IF 的最簡單形式。如果條件為真，則會執行 THEN 和 END IF 之間的陳述式。否則，它們會被略過。

範例

IF v_user_id <> 0 THEN
    UPDATE users SET email = v_email WHERE user_id = v_user_id;
END IF;

IF boolean-expression THEN
    statements
ELSE
    statements
END IF;

IF-THEN-ELSE 陳述式透過允許您指定一組替代陳述式來擴充 IF-THEN，這些陳述式應在條件不為真時執行。（請注意，這包括條件評估為 NULL 的情況。）

範例

IF parentid IS NULL OR parentid = ''
THEN
    RETURN fullname;
ELSE
    RETURN hp_true_filename(parentid) || '/' || fullname;
END IF;

IF v_count > 0 THEN
    INSERT INTO users_count (count) VALUES (v_count);
    RETURN 't';
ELSE
    RETURN 'f';
END IF;

IF boolean-expression THEN
    statements
[ ELSIF boolean-expression THEN
    statements
[ ELSIF boolean-expression THEN
    statements
    ...
]
]
[ ELSE
    statements ]
END IF;

有時不只有兩種替代方案。IF-THEN-ELSIF 提供了一種方便的方法來依序檢查多種替代方案。會連續測試 IF 條件，直到找到第一個為真的條件。然後執行相關的陳述式，之後控制權會傳遞到 END IF 之後的下一個陳述式。（不會測試任何後續的 IF 條件。）如果沒有任何 IF 條件為真，則執行 ELSE 區塊（如果有的話）。

以下是一個範例

IF number = 0 THEN
    result := 'zero';
ELSIF number > 0 THEN
    result := 'positive';
ELSIF number < 0 THEN
    result := 'negative';
ELSE
    -- hmm, the only other possibility is that number is null
    result := 'NULL';
END IF;

關鍵字 ELSIF 也可以拼寫為 ELSEIF。

完成相同任務的另一種方法是巢狀 IF-THEN-ELSE 陳述式，如下列範例所示：

IF demo_row.sex = 'm' THEN
    pretty_sex := 'man';
ELSE
    IF demo_row.sex = 'f' THEN
        pretty_sex := 'woman';
    END IF;
END IF;

但是，這種方法需要為每個 IF 寫入一個匹配的 END IF，因此當有很多替代方案時，它比使用 ELSIF 麻煩得多。

CASE search-expression
    WHEN expression [, expression [ ... ]] THEN
      statements
  [ WHEN expression [, expression [ ... ]] THEN
      statements
    ... ]
  [ ELSE
      statements ]
END CASE;

CASE 的簡單形式提供基於運算元相等性的條件式執行。search-expression 會被評估（一次），並連續與 WHEN 子句中的每個 expression 進行比較。如果找到匹配項，則執行對應的 statements，然後控制權傳遞到 END CASE 之後的下一個陳述式。（不會評估後續的 WHEN 表達式。）如果找不到匹配項，則執行 ELSE statements；但如果沒有 ELSE，則會引發 CASE_NOT_FOUND 例外狀況。

以下是一個簡單的範例

CASE x
    WHEN 1, 2 THEN
        msg := 'one or two';
    ELSE
        msg := 'other value than one or two';
END CASE;

CASE
    WHEN boolean-expression THEN
      statements
  [ WHEN boolean-expression THEN
      statements
    ... ]
  [ ELSE
      statements ]
END CASE;

CASE 的搜尋形式提供基於布林表示式真假的條件式執行。依序評估每個 WHEN 子句的 boolean-expression，直到找到一個產生 true 的子句。然後執行對應的 statements，然後控制權傳遞到 END CASE 之後的下一個陳述式。（不會評估後續的 WHEN 表示式。）如果找不到 true 結果，則執行 ELSE statements；但如果沒有 ELSE，則會引發 CASE_NOT_FOUND 例外狀況。

以下是一個範例

CASE
    WHEN x BETWEEN 0 AND 10 THEN
        msg := 'value is between zero and ten';
    WHEN x BETWEEN 11 AND 20 THEN
        msg := 'value is between eleven and twenty';
END CASE;

這種形式的 CASE 與 IF-THEN-ELSIF 完全等效，只是省略 ELSE 子句會導致錯誤，而不是不執行任何操作。

[ <<label>> ]
LOOP
    statements
END LOOP [ label ];

LOOP 定義一個無條件迴圈，它會無限重複，直到被 EXIT 或 RETURN 陳述式終止。巢狀迴圈中的 EXIT 和 CONTINUE 陳述式可以使用選用的 label 來指定這些陳述式所參考的迴圈。

EXIT [ label ] [ WHEN boolean-expression ];

如果未給定 label，則終止最內層的迴圈，並執行 END LOOP 後面的陳述式。如果給定了 label，則它必須是目前或某些外部層級的巢狀迴圈或區塊的標籤。然後終止命名的迴圈或區塊，並繼續執行迴圈/區塊的對應 END 後面的陳述式。

如果指定了 WHEN，則僅當 boolean-expression 為 true 時，才會發生迴圈結束。否則，控制權會傳遞到 EXIT 之後的陳述式。

EXIT 可以與所有類型的迴圈一起使用；它不限於與無條件迴圈一起使用。

與 BEGIN 區塊一起使用時，EXIT 會將控制權傳遞到區塊結束後的下一個陳述式。請注意，必須為此目的使用標籤；未標記的 EXIT 永遠不會被視為與 BEGIN 區塊匹配。（這是與 PostgreSQL 的 pre-8.4 版本的變更，該版本允許未標記的 EXIT 與 BEGIN 區塊匹配。）

範例

LOOP
    -- some computations
    IF count > 0 THEN
        EXIT;  -- exit loop
    END IF;
END LOOP;

LOOP
    -- some computations
    EXIT WHEN count > 0;  -- same result as previous example
END LOOP;

<<ablock>>
BEGIN
    -- some computations
    IF stocks > 100000 THEN
        EXIT ablock;  -- causes exit from the BEGIN block
    END IF;
    -- computations here will be skipped when stocks > 100000
END;

CONTINUE [ label ] [ WHEN boolean-expression ];

如果沒有給定 label，則開始最內層迴圈的下一次迭代。也就是說，迴圈體中剩餘的所有陳述式都會被跳過，並且控制權會返回到迴圈控制表達式（如果有的話），以確定是否需要另一次迴圈迭代。如果存在 label，則它指定將繼續執行的迴圈的標籤。

如果指定了 WHEN，則僅當 boolean-expression 為 true 時，才開始迴圈的下一次迭代。否則，控制權會傳遞到 CONTINUE 之後的陳述式。

CONTINUE 可以用於所有類型的迴圈；它不限於與無條件迴圈一起使用。

範例

LOOP
    -- some computations
    EXIT WHEN count > 100;
    CONTINUE WHEN count < 50;
    -- some computations for count IN [50 .. 100]
END LOOP;

[ <<label>> ]
WHILE boolean-expression LOOP
    statements
END LOOP [ label ];

當 boolean-expression 的計算結果為 true 時，WHILE 陳述式會重複一系列陳述式。在每次進入迴圈體之前，都會檢查該表達式。

例如：

WHILE amount_owed > 0 AND gift_certificate_balance > 0 LOOP
    -- some computations here
END LOOP;

WHILE NOT done LOOP
    -- some computations here
END LOOP;

[ <<label>> ]
FOR name IN [ REVERSE ] expression .. expression [ BY expression ] LOOP
    statements
END LOOP [ label ];

此形式的 FOR 會建立一個迴圈，該迴圈會迭代一系列整數值。變數 name 會自動定義為 integer 類型，並且僅存在於迴圈內（迴圈內會忽略變數名稱的任何現有定義）。給定範圍的下限和上限的兩個表達式會在進入迴圈時計算一次。如果未指定 BY 子句，則迭代步長為 1，否則為 BY 子句中指定的值，該值也會在迴圈進入時計算一次。如果指定了 REVERSE，則每次迭代後會減去步長值，而不是加上步長值。

整數 FOR 迴圈的一些範例：

FOR i IN 1..10 LOOP
    -- i will take on the values 1,2,3,4,5,6,7,8,9,10 within the loop
END LOOP;

FOR i IN REVERSE 10..1 LOOP
    -- i will take on the values 10,9,8,7,6,5,4,3,2,1 within the loop
END LOOP;

FOR i IN REVERSE 10..1 BY 2 LOOP
    -- i will take on the values 10,8,6,4,2 within the loop
END LOOP;

如果下限大於上限（或者在 REVERSE 的情況下小於上限），則根本不會執行迴圈體。不會引發錯誤。

如果 label 附加到 FOR 迴圈，則可以使用限定名稱來引用整數迴圈變數，使用該 label。

例外處理常式經常需要識別發生的特定錯誤。在 PL/pgSQL 中，有兩種方法可以取得有關目前例外的資訊：特殊變數和 GET STACKED DIAGNOSTICS 命令。

在例外處理常式中，特殊變數 SQLSTATE 包含與引發的例外相對應的錯誤碼（有關可能的錯誤碼的列表，請參閱表 A.1）。特殊變數 SQLERRM 包含與例外關聯的錯誤訊息。這些變數在例外處理常式之外未定義。

在例外處理常式中，也可以使用 GET STACKED DIAGNOSTICS 命令來取得有關目前例外的資訊，該命令的格式如下

GET STACKED DIAGNOSTICS variable { = | := } item [ , ... ];

每個 item 都是一個關鍵字，用於識別要賦予指定 variable 的狀態值（該值應具有正確的資料類型以接收它）。目前可用的狀態項目顯示在表 41.2中。

如果例外沒有為項目設定值，則將傳回空字串。

以下是一個範例

DECLARE
  text_var1 text;
  text_var2 text;
  text_var3 text;
BEGIN
  -- some processing which might cause an exception
  ...
EXCEPTION WHEN OTHERS THEN
  GET STACKED DIAGNOSTICS text_var1 = MESSAGE_TEXT,
                          text_var2 = PG_EXCEPTION_DETAIL,
                          text_var3 = PG_EXCEPTION_HINT;
END;